$! MAKE_BIBTEX.COM
$ on error then goto exit
$ on control_y then goto exit
$ old_verify = f$verify (1)
$!
$ if f$getsyi("HW_MODEL") .ge. 1024
$  then
$    arch_name = "Alpha"
$    ARCH_PREF = "AXP_"
$    PCFLAGS = "/opt/check=none/float=g_float/align=vax/nolist"
$  else
$    arch_name = "VAX"
$    ARCH_PREF = "VAX_"
$    PCFLAGS = "/opt/check=none/g_float/nolist"
$  endif
$ define/user CHANGEFILE "bibtex.vms-changes"
$!
$! Call Tangle to generate BIBTEX.PAS
$!
$ on warning then goto err_tangle
$ tangle bibtex
CHANGEFILE
$ on error then goto exit
$!
$! Compile the sources
$!
$ pasc 'PCFLAGS' /obj=.'ARCH_PREF'obj bibtex
$!
$! (Re)compile the internal command table
$!
$ set command/object=.'ARCH_PREF'obj bibtex_cli.cld
$!
$! Link 
$!
$ link /exe=.'ARCH_PREF'exe bibtex.'ARCH_PREF'obj,bibtex_cli.'ARCH_PREF'obj 
$!
$! Do not keep the compiled command table:
$!
$ delete/noconfirm/nolog bibtex_cli.'ARCH_PREF'obj;*
$!
$! Clean up environment, and exit
$!
$exit:
$ dummy=f$verify ('old_verify')
$ exit
$!
$! error messages:
$!
$! 1.) TANGLE problems
$err_tangle:
$ write sys$output "Tangle ERROR: Cannot find TANGLE, or (less likely)"
$ write sys$output -
  "                Tangle has found some problem in the source."
$ write sys$output -
  "                >>> Please correct the problem !! <<<"
$ goto exit